Listen
Oak Hill braucht ein schwarzes Brett: „Feed the cats“, „Get more torches“, „Plant wheat“. Du weißt nicht, wie viele Notizen es werden, also reicht eine Variable pro Notiz nicht. Heute bewahrst du alle Notizen in einer Liste auf. Du tippst sie am Laptop, und die Anzeigewand am Eingang zeigt die ganze Liste.
Neue Wörter
- Liste (in c0de: ARRAY): viele Werte desselben Typs unter einem Namen, einer nach dem anderen.
- Element: ein Wert in einer Liste.
- Index: die Nummer eines Elements in der Liste. Das erste Element hat den Index 0.
Was du brauchst
- deine Anzeigewand aus 2 × 1 Anzeigeblöcken, den Laptop und einen Auslöserblock mit einem Knopf
- ein neues, leeres Blatt in der c0de-Dimension
- aus dem Kreativinventar: die Blöcke, die du kennst (mit REPEAT und BREAK), und den neuen ARRAY-Typblock und EACH-Block
Die Idee
Denk an einen Einkaufszettel aus Papier. Er hat einen Namen, „Einkaufszettel“, aber viele Zeilen. Du kannst ihn von oben nach unten lesen, unten eine Zeile anfügen oder eine durchstreichen.
Eine Liste in einem Programm funktioniert genauso. Sie ist eine Variable, die viele Werte enthält, die Elemente, in einer festen Reihenfolge. Jedes Element hat eine Nummer, seinen Index. Computer beginnen bei 0 zu zählen, also ist das erste Element die Nummer 0, das zweite die Nummer 1 und so weiter. Eine Liste mit 3 Elementen hat die Indizes 0, 1 und 2.
In c0de heißt eine Liste ARRAY. Sie wächst von selbst, wenn du Elemente hinzufügst, und schrumpft, wenn du welche entfernst.
Das Programm
Das Programm notes kommt auf ein neues Blatt. Der Laptop und die Anzeigewand gehören beide dazu.
PROGRAM notes
NOOP
NOOP
FUNCTION board
BEGIN
VARIABLE notes ARRAY STRING
BEGIN
"Feed the cats"
END VARIABLE
VARIABLE note STRING
VARIABLE count INTEGER
REPEAT
BEGIN
CALL CLS
EACH line notes
BEGIN
CALL PRINT
PARAMETER value line ;
END EACH
CALL INPUT
PARAMETER variable note ;
BREAK note = "end" ;
CALL LEN
PARAMETER value notes ;
RESULT result count
CALL INSERT
PARAMETER array notes ;
PARAMETER index count ;
PARAMETER value note ;
RESULT result notes
END REPEAT TRUE ;
END FUNCTION
So baust du es
Die neuen Zeilen:
- Zeile 5: ein VARIABLE-Block bei x=6, ein LABEL
notes, ein ARRAY-Typblock und ein STRING-Typblock: eine Liste von Texten. - Zeilen 6 bis 8: die Startwerte der Liste: BEGIN bei x=6, ein LITERAL
"Feed the cats"bei x=7 und ein END-Block bei x=6, gefolgt von einem VARIABLE-Block. Weitere LITERAL-Blöcke in Zeile 7 ergäben weitere Startnotizen. - Zeile 14: ein EACH-Block bei x=7, ein LABEL
lineund ein LABELnotes. - Zeilen 15 bis 18: BEGIN bei x=7, das CALL PRINT von
linebei x=8 und x=9 und ein END-Block bei x=7, gefolgt von einem EACH-Block. - Zeile 21: ein BREAK-Block bei x=7, ein LABEL
note, ein OPERATOR=, ein LITERAL"end"und ein OPERATOR;. - Zeilen 25 bis 29: ein CALL-Block bei x=7 mit einem LABEL
INSERT, dann bei x=8 die PARAMETER-Zeilenarray(LABELnotes),index(LABELcount) undvalue(LABELnote), jede mit ihrem;, und die RESULT-Zeile mit den LABELsresultundnotes. - Zeile 30: ein END-Block bei x=6, ein REPEAT-Block, ein LITERAL
TRUEund ein OPERATOR;.
Starten
Binde die Anzeigewand und den Laptop an das Programm notes und die Funktion board und stelle den Auslöserblock genauso ein. Drück den Knopf. Die Wand zeigt die erste Notiz, „Feed the cats“.
Öffne den Laptop. Seine Eingabezeile zeigt INPUT note (STRING):. Tippe „Get more torches“ und drück Enter: Die Wand zeigt jetzt zwei Notizen. Tippe „Plant wheat“: drei.
Feed the cats
Get more torches
Plant wheat
Tippe „end“, um das Programm zu beenden. Die Notizen bleiben auf der Wand, aber die Liste selbst ist weg: Eine Variable lebt nur, solange ihr Programm läuft. Der nächste Start beginnt wieder mit „Feed the cats“.
Die Wand hat 8 Zeilen. Bei mehr als 8 Notizen rollen die ersten oben hinaus.
So funktioniert es
VARIABLE notes ARRAY STRINGmacht eine Liste von Texten. Ihre Startwerte stehen im Codeblock darunter: hier eine Notiz, „Feed the cats“, mit dem Index 0.- Die REPEAT-Schleife läuft für immer (
END REPEAT TRUE ;). Ihr einziger Ausweg ist das BREAK. CALL CLSlöscht die Bildschirme, dann gibt die EACH-Schleife die Liste aus. EACH geht vom Index 0 bis zum Ende durch die Liste. In jeder Runde enthält die Schleifenvariablelinedas nächste Element. Du musst nicht wissen, wie lang die Liste ist.CALL INPUTwartet auf die nächste Notiz vom Laptop.BREAK note = "end" ;verlässt die Schleife, wenn du „end“ tippst.CALL LENzählt die Elemente der Liste. Bei einer Notiz istcountgleich 1.CALL INSERTsetztnotebeim Indexcountin die Liste ein. Bei einer Notiz ist das der Index 1, direkt nach dem letzten Element: Die neue Notiz kommt ans Ende. INSERT gibt die längere Liste als Ergebnis zurück, undRESULT result notesspeichert sie wieder innotes.
Du kannst ein Element auch mit seinem Index lesen und ändern: notes[0] ist „Feed the cats“, und ASSIGN notes[0] "Feed the dog" ; ändert es. Der Index kann eine Zahl oder eine Variable sein, zum Beispiel notes[i], aber keine Rechnung: notes[i + 1] funktioniert nicht. Rechne den Index zuerst in eine Variable.
Probier es selbst
- Zeige jede Notiz mit ihrer Nummer und lass den Spieler eine Notiz löschen: Wenn er „delete“ tippt, fragt der Laptop nach der Nummer der Notiz.
Lösung
Eine FOR-Schleife von 0 bis count - 1 gibt jede Notiz mit ihrem Index aus, i ⊕ ": " ⊕ notes[i]. Bei „delete“ liest ein zweites INPUT die Nummer, und REMOVE nimmt das Element aus der Liste. Die Elemente dahinter rücken um eins auf.
PROGRAM notes
NOOP
NOOP
FUNCTION board
BEGIN
VARIABLE notes ARRAY STRING
BEGIN
"Feed the cats"
END VARIABLE
VARIABLE note STRING
VARIABLE count INTEGER
VARIABLE number INTEGER
REPEAT
BEGIN
CALL LEN
PARAMETER value notes ;
RESULT result count
CALL CLS
FOR i INTEGER 0 ; count - 1 ;
BEGIN
CALL PRINT
PARAMETER value i ⊕ ": " ⊕ notes[i] ;
END FOR
CALL INPUT
PARAMETER variable note ;
BREAK note = "end" ;
IF note = "delete" ;
BEGIN
CALL INPUT
PARAMETER variable number ;
CALL REMOVE
PARAMETER container notes ;
PARAMETER index number ;
RESULT result notes
END
ELSE
BEGIN
CALL INSERT
PARAMETER array notes ;
PARAMETER index count ;
PARAMETER value note ;
RESULT result notes
END IF
END REPEAT TRUE ;
END FUNCTIONNach „Get more torches“, „Plant wheat“, „delete“ und 0 zeigt die Wand „0: Get more torches“ und „1: Plant wheat“. Eine Nummer, die nicht in der Liste ist, zum Beispiel 7, lässt das Programm mit INDEX_OUT_OF_BOUNDS abstürzen.
- Zeige über der Liste die Anzahl der Notizen.
Lösung
Verschiebe das CALL LEN an den Anfang der Schleife und gib vor der EACH-Schleife "Notes: " ⊕ count aus.
PROGRAM notes
NOOP
NOOP
FUNCTION board
BEGIN
VARIABLE notes ARRAY STRING
BEGIN
"Feed the cats"
END VARIABLE
VARIABLE note STRING
VARIABLE count INTEGER
REPEAT
BEGIN
CALL LEN
PARAMETER value notes ;
RESULT result count
CALL CLS
CALL PRINT
PARAMETER value "Notes: " ⊕ count ;
EACH line notes
BEGIN
CALL PRINT
PARAMETER value line ;
END EACH
CALL INPUT
PARAMETER variable note ;
BREAK note = "end" ;
CALL INSERT
PARAMETER array notes ;
PARAMETER index count ;
PARAMETER value note ;
RESULT result notes
END REPEAT TRUE ;
END FUNCTIONMehr dazu
- Typen, Variablen und Konstanten und EACH-Schleifen in der Anleitung
- TYPE_ARRAY im Handbuch Daten, EACH im Handbuch Anweisungen
- LEN, INSERT und REMOVE im Handbuch Funktionen