Würfeln
Ein Würfel für jedes Spiel: ein W6 für Brettspiele, ein W20 für Abenteuer, drei auf einmal, mit den Augenzahlen und ihrer Summe auf einem Anzeigeblock. Mit einem Startwert würfelt er bei jedem Lauf dieselben Zahlen – praktisch zum Testen und für ein Spiel, in dem alle dasselbe Glück haben sollen.
Funktionen: RANDOM, RANDOMIZE, INT und FIX
Was du brauchst
Einen Auslöserblock mit einem Knopf, einen Anzeigeblock (16 Spalten und 8 Zeilen reichen) und eine nicht initialisierte Variablenkarte für das Ergebnis total. Wenn du magst, die Variablenkarten sides, count und seed vom Typ INTEGER; ohne sie ist der Würfel ein einzelner W6. Für „INT oder FIX?“: zwei nicht initialisierte Karten für den Auslöserblock.
Die Idee
RANDOM gibt ein FLOAT von 0 bis unter 1. Ein Würfel braucht eine ganze Zahl von 1 bis sides, jede gleich wahrscheinlich. Mal sides genommen, liegt die Zahl zwischen 0 und knapp unter sides; plus 1 zwischen 1 und knapp unter sides + 1. INT rundet auf die ganze Zahl darunter ab: Bei einem W6 wird alles von 1,0 bis 1,999… zu 1, alles von 6,0 bis 6,999… zu 6. Jede der sechs Zahlen bekommt ein gleich breites Stück, also ist jede gleich wahrscheinlich.
Die Zahlen von RANDOM sind nicht wirklich zufällig: Sie werden eine nach der anderen aus einem Startwert berechnet, dem Seed. Jeder Prozess bekommt seinen eigenen Generator mit eigenem Seed, darum ist jeder Lauf anders. Mit RANDOMIZE setzt du den Seed selbst, und von da an würfelt der Prozess jedes Mal dieselbe Folge.
Das Programm
PROGRAM anydie
NOOP
INCLUDE c0de/math
NOOP
FUNCTION roll
PARAMETER sides INTEGER 6
PARAMETER count INTEGER 1
PARAMETER seed INTEGER 0
RESULT total INTEGER
BEGIN
VARIABLE chance FLOAT
VARIABLE die INTEGER
IF seed ≠ 0 ;
BEGIN
CALL c0de/math/RANDOMIZE
PARAMETER seed seed ;
END IF
CALL CLS
FOR i INTEGER 1 ; count ;
BEGIN
CALL c0de/math/RANDOM
RESULT result chance
CALL c0de/math/INT
PARAMETER value chance * sides + 1 ;
RESULT result die
CALL PRINT
PARAMETER value "D" ⊕ sides ⊕ ": " ⊕ die ;
ASSIGN total total + die ;
END FOR
CALL PRINT
PARAMETER value "Total: " ⊕ total ;
END FUNCTIONSo baust und startest du es
- Setze den Anzeigeblock, klicke ihn mit der rechten Maustaste an, klicke die Knöpfe, bis sie
anydieundrollzeigen, und klicke auf ✔. - Stelle den Auslöserblock auf das Programm
anydieund die Funktionrollein. Lege eine nicht initialisierte Variablenkarte fürtotalin sein Eingabeinventar. - Drück den Knopf. Der Anzeigeblock zeigt etwa
D6: 4undTotal: 4; drück noch einmal für eine neue Zahl. - Lege jetzt die Karten
sides= 20,count= 3 undseed= 42 dazu und drück den Knopf. Der Anzeigeblock zeigt:
D20: 15
D20: 4
D20: 6
Total: 25Starte es noch einmal mit denselben drei Karten: dieselben drei Zahlen. Genau das prüft auch der Test dieses Programms. Lass die Karte seed weg, und der Würfel ist wieder zufällig.

So funktioniert es
- Vorgabewerte statt Karten.
sides,countundseedhaben Vorgabewerte, darum startet der Auslöserblock auch ohne ihre Karten. Eine Parameterkarte, wenn es eine gibt, ersetzt den Vorgabewert. - In diesem Programm heißt Seed 0 „wirklich zufällig“. RANDOMIZE läuft nur, wenn
seednicht 0 ist. Der Seed gilt nur für den aktuellen Prozess, er ändert also weder die Würfel anderer Programme noch den nächsten Lauf ohne die Karte. chance * sides + 1geht direkt in INT: Eine PARAMETER-Zeile nimmt jeden Ausdruck. Das Ergebnisdieist ein INTEGER, fertig für den Text.- Warum INT und nicht ROUND? ROUND würde 0,0 bis 0,499… zu 0 machen – eine siebte Zahl, und 1 und 6 bekämen nur ein halbes Stück. INT gibt jeder Zahl ein ganzes Stück.
INT oder FIX?
Beide machen aus einem FLOAT einen INTEGER. INT rundet ab, FIX schneidet die Nachkommastellen ab. Für positive Zahlen ist das dasselbe, der Würfel könnte also beide nehmen. Unter 0 unterscheiden sie sich: INT macht aus -0,5 eine -1, FIX eine 0.
Das zählt bei einem zufälligen Schritt nach links, nirgendwohin oder nach rechts, -1, 0 oder 1: chance * 3 - 1 liegt zwischen -1 und knapp unter 2. Dieses Programm würfelt ihn 120-mal und zählt, wie oft jeder Schritt vorkommt, einmal mit INT und einmal mit FIX:
PROGRAM randomsteps
NOOP
INCLUDE c0de/math
NOOP
FUNCTION compare
PARAMETER rolls INTEGER 120
PARAMETER seed INTEGER 42
RESULT withInt ARRAY INTEGER
RESULT withFix ARRAY INTEGER
BEGIN
VARIABLE chance FLOAT
VARIABLE step INTEGER
VARIABLE slot INTEGER
FOR i INTEGER 0 ; 2 ;
BEGIN
ASSIGN withInt[i] 0 ;
ASSIGN withFix[i] 0 ;
END FOR
CALL c0de/math/RANDOMIZE
PARAMETER seed seed ;
FOR i INTEGER 1 ; rolls ;
BEGIN
CALL c0de/math/RANDOM
RESULT result chance
CALL c0de/math/INT
PARAMETER value chance * 3 - 1 ;
RESULT result step
ASSIGN slot step + 1 ;
ASSIGN withInt[slot] withInt[slot] + 1 ;
CALL c0de/math/FIX
PARAMETER value chance * 3 - 1 ;
RESULT result step
ASSIGN slot step + 1 ;
ASSIGN withFix[slot] withFix[slot] + 1 ;
END FOR
END FUNCTIONNimm denselben Auslöserblock: Nimm die Karten des Würfels heraus, stelle ihn auf randomsteps und compare ein und lege zwei nicht initialisierte Karten für die Ergebnisse withInt und withFix hinein. Das Programm gibt nichts aus, die Anzeige bleibt also, wie sie ist; für die 120 Würfe braucht der Cursor etwa eine Minute. Mit dem Seed 42 ist withInt gleich [46, 27, 47] und withFix gleich [0, 73, 47]. Mit INT kommen alle drei Schritte etwa gleich oft vor. FIX macht alles von -1 bis 0 zu 0, also kommt -1 nie vor und 0 ist doppelt so wahrscheinlich. Nimm INT für Zufallszahlen, die negativ sein können; FIX ist zum Abschneiden von Nachkommastellen da, etwa für einen Preis ohne Cent.
Probier es selbst
- Eine Schatztruhe wählt eine Belohnung aus einer Liste: Diamant, Smaragd, Goldbarren, Eisenbarren oder Brot. Zeige sie auf dem Anzeigeblock.
Lösung
Derselbe Trick mit der Länge der Liste statt sides und ohne das + 1, denn Indizes beginnen bei 0: INT macht aus chance * count eine Zahl von 0 bis count - 1.
PROGRAM reward
NOOP
INCLUDE c0de/math
VARIABLE prizes ARRAY STRING
BEGIN
"diamond" "emerald" "gold_ingot" "iron_ingot" "bread"
END VARIABLE
NOOP
FUNCTION pick
PARAMETER seed INTEGER 0
RESULT prize STRING
BEGIN
VARIABLE chance FLOAT
VARIABLE count INTEGER
VARIABLE index INTEGER
IF seed ≠ 0 ;
BEGIN
CALL c0de/math/RANDOMIZE
PARAMETER seed seed ;
END IF
CALL LEN
PARAMETER value prizes ;
RESULT result count
CALL c0de/math/RANDOM
RESULT result chance
CALL c0de/math/INT
PARAMETER value chance * count ;
RESULT result index
ASSIGN prize prizes[index] ;
CALL PRINT
PARAMETER value "You win: " ⊕ prize ;
END FUNCTIONMit der Karte seed = 42 ist die Belohnung immer iron_ingot.
- Warum würfelt das Programm nach
RANDOMIZEmit 42 dieselben Zahlen, obwohl jeder Prozess seinen eigenen Zufallsgenerator hat?
Lösung
Jeder Generator berechnet seine Zahlen auf dieselbe Weise; nur der Startwert ist verschieden. RANDOMIZE setzt den Startwert, also berechnen zwei Prozesse mit demselben Seed dieselbe Folge: Das erste RANDOM gibt dasselbe FLOAT, also ist der erste Würfel derselbe, und so weiter. Ein anderer Seed, etwa 7, gibt eine andere Folge – wieder bei jedem Lauf dieselbe.
Mehr dazu
- Die Handbuchseiten von RANDOM, RANDOMIZE, INT und FIX und ganz c0de/math
- Runden in der Anleitung
- Anzeigeblock und PRINT
- Bibliotheken benutzen: der erste Würfel im Pfad „Programmieren lernen“