Eine Tür mit Passwort
Eine Eisentür, die aufgeht, wenn du auf dem Laptop daneben das Passwort tippst. Während du tippst, zeigt der Laptop nur Sternchen. Das Passwort steht nirgends in der Welt: nicht auf dem Blatt, nicht in einer Karte. Es liegt in deinem Tresor, und wenn du den Server verlässt, vergisst der Tresor es – die Tür bleibt zu, bis du ein neues festlegst.
Funktionen: SET_SECRET, HAS_SECRET, DELETE_SECRET und INPUT mit hide
Was du brauchst
- ein leeres Blatt, einen SECRET-Block (ein CONSTANT-Block und ein Eisenbarren) und zwei TAG-Blöcke
- drei Auslöserblöcke mit je einem Knopf: einen für die Tür, einen zum Festlegen des Passworts, einen zum Vergessen
- zwei Laptops, einen Komparator und eine Eisentür
- keine Rechte: Die Tür geht über Redstone auf, und das darf jeder Spieler
Die Idee
Ein Passwort auf dem Blatt ist kein Geheimnis: Jeder, der das Blatt besucht, kann seine LITERAL-Blöcke lesen. Eine verborgene Karte ist besser, aber ihr Wert liegt trotzdem in der Welt, in einem Auslöserblock. c0de/security hat einen besseren Ort: deinen Tresor. Jeder Spieler hat einen, solange er online ist. SET_SECRET legt einen Wert unter einem Namen hinein, und eine SECRET-Zeile liest ihn wieder, wie eine Konstante.
Der Tresor hat zwei Regeln, die die Tür prägen:
- Nur du. Ein Programm bekommt nur den Tresor des Spielers, der es gestartet hat, und nur, wenn diesem Spieler das Blatt gehört. Drückt jemand anderes den Knopf, hat das Programm keinen Tresor, und c0de/security löst VAULT_UNAVAILABLE aus. Die Tür hört also nur auf dich, und auf dich nur mit dem Passwort – wie die PIN eines Handys.
- Nur, solange du online bist. Der Tresor ist leer, wenn du dem Server beitrittst. Die Tür braucht also einen Weg, das Passwort festzulegen (
setup), und einen Weg zu fragen, ob es eins gibt: HAS_SECRET. Eine SECRET-Zeile für einen Namen, der nicht im Tresor ist, löst SECRET_NOT_FOUND aus.
Auch das Tippen soll geheim sein: INPUT mit PARAMETER hide TRUE ; zeigt für jedes Zeichen ein *, und der Laptop schreibt die Zeile als ***. Und der Tag security: "sensitive" hält das Passwort aus dem Debugging-Werkzeug heraus.
Die Tür selbst öffnet der Exit-Code: Ein Komparator neben dem Auslöserblock gibt ein Signal so stark wie der Exit-Code des letzten Prozesses aus. EXIT 1 ; für das richtige Passwort, 0 für alles andere.
Das Programm
PROGRAM passdoor
NOOP
INCLUDE c0de/security
NOOP
CONSTANT NAME STRING "doorPassword"
NOOP
FUNCTION check
RESULT right BOOLEAN
BEGIN
SECRET doorPassword STRING
VARIABLE typed STRING TAG(security: "sensitive")
CALL PRINT
PARAMETER value "Password:" ;
CALL INPUT
PARAMETER variable typed ;
PARAMETER hide TRUE ;
ASSIGN right typed = doorPassword ;
END FUNCTION
NOOP
FUNCTION setup
BEGIN
VARIABLE password STRING TAG(security: "sensitive")
VARIABLE again STRING TAG(security: "sensitive")
CALL CLS
CALL PRINT
PARAMETER value "New password:" ;
CALL INPUT
PARAMETER variable password ;
PARAMETER hide TRUE ;
CALL PRINT
PARAMETER value "Repeat it:" ;
CALL INPUT
PARAMETER variable again ;
PARAMETER hide TRUE ;
IF password = "" OR password ≠ again ;
BEGIN
CALL PRINT
PARAMETER value "Not the same twice. Nothing changed." ;
RETURN
END IF
CALL c0de/security/SET_SECRET
PARAMETER name NAME ;
PARAMETER value password ;
CALL PRINT
PARAMETER value "Password set." ;
END FUNCTION
NOOP
FUNCTION open
BEGIN
VARIABLE known BOOLEAN
VARIABLE right BOOLEAN
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/HAS_SECRET problem
PARAMETER name NAME ;
RESULT result known
IF problem.code = VAULT_UNAVAILABLE ;
BEGIN
CALL PRINT
PARAMETER value "This door only listens to its owner." ;
RETURN
END IF
IF NOT known ;
BEGIN
CALL PRINT
PARAMETER value "No password yet. Run setup first." ;
RETURN
END IF
CALL check
RESULT right right
IF NOT right ;
BEGIN
CALL PRINT
PARAMETER value "Wrong password." ;
RETURN
END IF
CALL PRINT
PARAMETER value "Welcome home!" ;
EXIT 1 ;
END FUNCTION
NOOP
FUNCTION forget
BEGIN
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/DELETE_SECRET problem
PARAMETER name NAME ;
IF problem.code = SECRET_NOT_FOUND ;
BEGIN
CALL PRINT
PARAMETER value "There is no password to forget." ;
RETURN
END IF
CALL PRINT
PARAMETER value "Password forgotten. The door stays shut." ;
END FUNCTIONSo baust und startest du es
- Setze die Eisentür in die Wand. Platziere den Auslöserblock für die Tür daneben, mit einem Komparator dazwischen, der vom Auslöserblock zur Tür zeigt. Setze einen Knopf an den Auslöserblock und den Laptop daneben.
- Stelle den Auslöserblock auf das Programm
passdoorund die Funktionopenein und seinen Knopf Starten durch auf Nur mich. Binde auch den Laptop anpassdoorundopen. - Richte drinnen in deiner Basis den zweiten Auslöserblock mit einem Knopf für die Funktion
setupein, mit einem zweiten Laptop, der anpassdoorundsetupgebunden ist, und den dritten Auslöserblock fürforget. Stelle auch bei ihnen Starten durch auf Nur mich. - Drücke den Knopf von
setup. Der Laptop fragtNew password:; tippe das Passwort und drücke Enter. Die Zeile zeigt***. Tippe es nachRepeat it:noch einmal. Der Laptop antwortetPassword set.

- Drücke den Knopf der Tür. Der Laptop fragt
Password:. Tippe das Passwort: Die Tür geht auf, und der Laptop sagtWelcome home!. Ein falsches Passwort bekommtWrong password., und die Tür bleibt zu.

Um die Tür zu schließen, drücke den Knopf noch einmal: Solange ein Prozess läuft, gibt der Komparator 0 aus, die Tür geht also zu, während der Laptop nach dem Passwort fragt.
Verlasse den Server, tritt wieder bei und drücke den Knopf: No password yet. Run setup first. Der Tresor hat das Passwort vergessen. Der Knopf von forget macht dasselbe mit Absicht: Password forgotten. The door stays shut.
So funktioniert es
- Der Name des Geheimnisses ist die Konstante
NAME,"doorPassword". SET_SECRET, HAS_SECRET und DELETE_SECRET nehmen ihn als STRING. Die SECRET-Zeile inchecknennt dasselbe Geheimnis mit einem LABEL,doorPassword, denn eine SECRET-Zeile ist eine Deklaration, wie CONSTANT. setupliest das Passwort zweimal mit verborgenem INPUT, vergleicht die beiden und legt es mit SET_SECRET in den Tresor. Der Typ des Geheimnisses ist der Typ vonvalue, hier STRING. Ein zweitessetupersetzt das alte Passwort.openfragt, bevor es liest. HAS_SECRET antwortet TRUE oder FALSE, und es ist ein CALL, also kann die FehlervariableproblemVAULT_UNAVAILABLE abfangen: Dann hat ein Besucher den Knopf gedrückt (wenn Starten durch Spieler erlaubt), und die Tür sagt das, statt abzustürzen. Erst wenn das Passwort da ist, ruftopendie Funktioncheckauf.checkliest das Geheimnis. Der Wert wird gelesen, wenn der Cursor die SECRET-Zeile ausführt, darum istcheckeine eigene Funktion, die erst nach HAS_SECRET läuft. Ihr Wert ist sensibel: Das Debugging-Werkzeug zeigt***fürdoorPassword.typedhat den Tagsecurity: "sensitive", undpasswordundagaininsetupauch – ohne ihn würde das Debugging-Werkzeug zeigen, was du getippt hast.- Abstürze öffnen Türen. Ein Prozess, der abstürzt, endet mit dem Exit-Code 15, und der öffnet die Tür auch. Darum vermeidet
openjeden Absturz, den es kann: Es prüft zuerst mit HAS_SECRET und fängt VAULT_UNAVAILABLE ab. forgetentfernt das Geheimnis mit DELETE_SECRET. Ein Geheimnis, das nicht da ist, löst SECRET_NOT_FOUND aus, undproblemfängt es ab.
Probier es selbst
- Gib dem Besucher drei Versuche, bevor die Tür aufgibt.
Lösung
PROGRAM passdoortries
NOOP
INCLUDE c0de/security
NOOP
CONSTANT NAME STRING "doorPassword"
NOOP
FUNCTION check
RESULT right BOOLEAN
BEGIN
SECRET doorPassword STRING
VARIABLE typed STRING TAG(security: "sensitive")
CALL PRINT
PARAMETER value "Password:" ;
CALL INPUT
PARAMETER variable typed ;
PARAMETER hide TRUE ;
ASSIGN right typed = doorPassword ;
END FUNCTION
NOOP
FUNCTION setup
BEGIN
VARIABLE password STRING TAG(security: "sensitive")
VARIABLE again STRING TAG(security: "sensitive")
CALL CLS
CALL PRINT
PARAMETER value "New password:" ;
CALL INPUT
PARAMETER variable password ;
PARAMETER hide TRUE ;
CALL PRINT
PARAMETER value "Repeat it:" ;
CALL INPUT
PARAMETER variable again ;
PARAMETER hide TRUE ;
IF password = "" OR password ≠ again ;
BEGIN
CALL PRINT
PARAMETER value "Not the same twice. Nothing changed." ;
RETURN
END IF
CALL c0de/security/SET_SECRET
PARAMETER name NAME ;
PARAMETER value password ;
CALL PRINT
PARAMETER value "Password set." ;
END FUNCTION
NOOP
FUNCTION open
BEGIN
VARIABLE known BOOLEAN
VARIABLE right BOOLEAN
VARIABLE tries INTEGER
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/HAS_SECRET problem
PARAMETER name NAME ;
RESULT result known
IF problem.code = VAULT_UNAVAILABLE ;
BEGIN
CALL PRINT
PARAMETER value "This door only listens to its owner." ;
RETURN
END IF
IF NOT known ;
BEGIN
CALL PRINT
PARAMETER value "No password yet. Run setup first." ;
RETURN
END IF
REPEAT
BEGIN
CALL check
RESULT right right
ASSIGN tries tries + 1 ;
IF NOT right AND tries < 3 ;
BEGIN
CALL PRINT
PARAMETER value "Wrong password, try again." ;
END IF
END REPEAT NOT right AND tries < 3 ;
IF NOT right ;
BEGIN
CALL PRINT
PARAMETER value "Three wrong passwords. Go away!" ;
RETURN
END IF
CALL PRINT
PARAMETER value "Welcome home!" ;
EXIT 1 ;
END FUNCTION
NOOP
FUNCTION forget
BEGIN
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/DELETE_SECRET problem
PARAMETER name NAME ;
IF problem.code = SECRET_NOT_FOUND ;
BEGIN
CALL PRINT
PARAMETER value "There is no password to forget." ;
RETURN
END IF
CALL PRINT
PARAMETER value "Password forgotten. The door stays shut." ;
END FUNCTIONDie REPEAT-Schleife ruft check auf, bis das Passwort stimmt oder tries 3 erreicht. Jeder Aufruf von check liest das Geheimnis neu – das ist erlaubt, eine SECRET-Zeile darf so oft laufen, wie du willst.
setupersetzt das Passwort, ohne zu fragen. Lass es zuerst nach dem alten Passwort fragen, wenn es eins gibt – wie ein Handy, das die alte PIN will, bevor du eine neue wählst.
Lösung
PROGRAM passdoorchange
NOOP
INCLUDE c0de/security
NOOP
CONSTANT NAME STRING "doorPassword"
NOOP
FUNCTION check
RESULT right BOOLEAN
BEGIN
SECRET doorPassword STRING
VARIABLE typed STRING TAG(security: "sensitive")
CALL PRINT
PARAMETER value "Password:" ;
CALL INPUT
PARAMETER variable typed ;
PARAMETER hide TRUE ;
ASSIGN right typed = doorPassword ;
END FUNCTION
NOOP
FUNCTION setup
BEGIN
VARIABLE password STRING TAG(security: "sensitive")
VARIABLE again STRING TAG(security: "sensitive")
VARIABLE known BOOLEAN
VARIABLE right BOOLEAN
CALL CLS
CALL c0de/security/HAS_SECRET
PARAMETER name NAME ;
RESULT result known
IF known ;
BEGIN
CALL check
RESULT right right
IF NOT right ;
BEGIN
CALL PRINT
PARAMETER value "Wrong password. Nothing changed." ;
RETURN
END IF
END IF
CALL PRINT
PARAMETER value "New password:" ;
CALL INPUT
PARAMETER variable password ;
PARAMETER hide TRUE ;
CALL PRINT
PARAMETER value "Repeat it:" ;
CALL INPUT
PARAMETER variable again ;
PARAMETER hide TRUE ;
IF password = "" OR password ≠ again ;
BEGIN
CALL PRINT
PARAMETER value "Not the same twice. Nothing changed." ;
RETURN
END IF
CALL c0de/security/SET_SECRET
PARAMETER name NAME ;
PARAMETER value password ;
CALL PRINT
PARAMETER value "Password set." ;
END FUNCTION
NOOP
FUNCTION open
BEGIN
VARIABLE known BOOLEAN
VARIABLE right BOOLEAN
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/HAS_SECRET problem
PARAMETER name NAME ;
RESULT result known
IF problem.code = VAULT_UNAVAILABLE ;
BEGIN
CALL PRINT
PARAMETER value "This door only listens to its owner." ;
RETURN
END IF
IF NOT known ;
BEGIN
CALL PRINT
PARAMETER value "No password yet. Run setup first." ;
RETURN
END IF
CALL check
RESULT right right
IF NOT right ;
BEGIN
CALL PRINT
PARAMETER value "Wrong password." ;
RETURN
END IF
CALL PRINT
PARAMETER value "Welcome home!" ;
EXIT 1 ;
END FUNCTION
NOOP
FUNCTION forget
BEGIN
VARIABLE problem ERROR
CALL CLS
CALL c0de/security/DELETE_SECRET problem
PARAMETER name NAME ;
IF problem.code = SECRET_NOT_FOUND ;
BEGIN
CALL PRINT
PARAMETER value "There is no password to forget." ;
RETURN
END IF
CALL PRINT
PARAMETER value "Password forgotten. The door stays shut." ;
END FUNCTIONsetup fragt zuerst HAS_SECRET. Gibt es ein Passwort, ruft es check auf und hört nach einem falschen mit Wrong password. Nothing changed. auf. Ohne Passwort, beim ersten setup nach dem Beitreten, fragt es gleich nach dem neuen.
Mehr dazu
- c0de/security: SET_SECRET, HAS_SECRET, DELETE_SECRET
- c0de/security und Geheimnisse im Tresor im Leitfaden
- SECRET und TAG im Handbuch Daten, Verborgene Karten im Handbuch Werkzeuge
- INPUT und der Laptop
- Exit-Codes und Fehler
- Schlüssel aufbewahren: Geheimnisse, die bleiben, wenn du gehst