This page in English

Eine Uhr an der Wand ​

Eine Digitaluhr auf einer Anzeigewand, die die echte Uhrzeit zeigt und jede Sekunde weiterspringt. Ein Zeitgeberblock startet das Programm immer wieder; jeder Lauf liest die Zeit einmal und schreibt sie auf den Bildschirm.

Funktionen: NOW, HOUR, MINUTE, SECOND und FORMAT aus c0de/strings.

Was du brauchst

Einen Zeitgeberblock, einen Hebel, um ihn anzuhalten, wenn du das Programm änderst, und eine Anzeigewand aus 2 × 1 Anzeigeblöcken (32 Spalten, 8 Zeilen). Keine Variablenkarten: Das Programm hat keine Parameter und keine Ergebnisse.

Die Idee ​

Ein Programm kann nicht dasitzen und auf die Uhr schauen: Es läuft, erledigt seine Arbeit und endet. Für etwas, das sich ständig ändert, startet ein Zeitgeberblock dieselbe Funktion immer wieder, hier alle 20 Ticks, also etwa einmal pro Sekunde. Jeder Lauf fragt NOW nach der aktuellen Zeit, zerlegt sie mit HOUR, MINUTE und SECOND und schreibt 09:05:03 auf den Bildschirm.

Ein TIME-Wert ist ein Zeitpunkt, gezählt in Millisekunden seit Anfang 1970. HOUR, MINUTE und SECOND machen daraus die Zahlen, die du kennst, in der Zeitzone des Servers. FORMAT füllt sie dann mit einer führenden Null auf, damit 9 Uhr als 09 erscheint und nicht als 9.

Das Programm ​

c0de
PROGRAM wallclock
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
NOOP
FUNCTION tick
BEGIN
    VARIABLE now TIME
    VARIABLE part INTEGER
    VARIABLE text STRING
    VARIABLE digits STRING
    CALL c0de/time/NOW
        RESULT result now
    CALL c0de/time/HOUR
        PARAMETER time now ;
        RESULT result part
    CALL c0de/strings/FORMAT
        PARAMETER value part ;
        PARAMETER format "%02d" ;
        RESULT result text
    CALL c0de/time/MINUTE
        PARAMETER time now ;
        RESULT result part
    CALL c0de/strings/FORMAT
        PARAMETER value part ;
        PARAMETER format ":%02d" ;
        RESULT result digits
    ASSIGN text text ⊕ digits ;
    CALL c0de/time/SECOND
        PARAMETER time now ;
        RESULT result part
    CALL c0de/strings/FORMAT
        PARAMETER value part ;
        PARAMETER format ":%02d" ;
        RESULT result digits
    CALL LOCATE
        PARAMETER row 3 ;
        PARAMETER column 12 ;
    CALL PRINT
        PARAMETER value text ⊕ digits ;
END FUNCTION

Aufbauen und starten ​

  1. Baue die Anzeigewand: zwei Anzeigeblöcke nebeneinander, die in dieselbe Richtung zeigen.
  2. Binde sie an das Programm wallclock und die Funktion tick (Anzeigeblock mit rechts anklicken, Programm und Funktion wählen, auf ✔ klicken).
  3. Setze einen Zeitgeberblock und stelle ihn auf wallclock / tick und einen Abstand von 20 Ticks ein.
  4. Setze einen Hebel neben den Zeitgeberblock und lass ihn aus. Solange der Hebel an ist, pausiert der Zeitgeberblock.

Die Uhr erscheint in der Mitte der Wand und zählt die Sekunden. Um das Programm zu ändern, leg zuerst den Hebel um, damit der Zeitgeberblock anhält: Ein laufender Prozess sperrt das Blatt.

a display wall of 2 × 1 display blocks showing the time 09:05:03 in the middle, the timer block in front of it

So funktioniert es ​

  • Ein NOW, viele Teile. Das Programm fragt die Zeit einmal ab und gibt now an HOUR, MINUTE und SECOND weiter. Ohne time würde jede von ihnen selbst auf die Uhr schauen – und um 09:59:59,990 könnte HOUR noch 9 sagen, während MINUTE schon 0 sagt: eine Uhr, die für eine Sekunde auf 09:00:00 zurückspringt.
  • FORMAT füllt die Zahlen auf. %02d schreibt eine ganze Zahl mindestens zwei Stellen breit und füllt sie mit Nullen auf. Das Format :%02d setzt den Doppelpunkt gleich mit davor.
  • LOCATE statt CLS. Die neue Zeit überschreibt die alte in Zeile 3, Spalte 12. Den Bildschirm vorher zu löschen, würde ihn flackern lassen.
  • Auch der Cursor braucht Zeit. Er geht eine Zeile pro Tick weiter, und tick braucht etwa 18 Zeilen. Bei einem Abstand von 20 Ticks endet ein Lauf, bevor der nächste fällig ist. Ein Zeitgeberblock startet einen neuen Prozess erst, wenn der letzte beendet ist; ein langsameres Programm würde also Sekunden auslassen.
  • Die Zeitzone ist die des Servers. Auf einem Server in Berlin wird 23:59:59 UTC als 00:59:59 angezeigt.

Probier es selbst ​

  1. Zeige unter der Uhrzeit das Datum, etwa 2026-11-12.
Lösung
c0de
PROGRAM wallclock
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
NOOP
FUNCTION tick
BEGIN
    VARIABLE now TIME
    VARIABLE clock STRING
    VARIABLE date STRING
    CALL c0de/time/NOW
        RESULT result now
    CALL c0de/strings/FORMAT
        PARAMETER value now ;
        PARAMETER format "%tT" ;
        RESULT result clock
    CALL c0de/strings/FORMAT
        PARAMETER value now ;
        PARAMETER format "%tF" ;
        RESULT result date
    CALL LOCATE
        PARAMETER row 3 ;
        PARAMETER column 12 ;
    CALL PRINT
        PARAMETER value clock ;
    CALL LOCATE
        PARAMETER row 4 ;
        PARAMETER column 11 ;
    CALL PRINT
        PARAMETER value date ;
END FUNCTION

Für TIME-Werte kennt FORMAT eigene Codes: %tT ist die Uhrzeit und %tF das Datum. Je ein Aufruf ersetzt HOUR, MINUTE, SECOND und das Auffüllen. Die Einzelteile lohnen sich, wenn du mit den Zahlen rechnen willst, wie in der nächsten Übung.

  1. Begrüße die Spieler: „Good morning“ vor zwölf Uhr, „Good afternoon“ vor 18 Uhr, „Good evening“ danach und „Good night“ vor 6 Uhr.
Lösung
c0de
PROGRAM wallclock
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
INCLUDE c0de/math
VARIABLE greetings ARRAY STRING
BEGIN
    "Good night    " "Good morning  " "Good afternoon" "Good evening  "
END VARIABLE
NOOP
FUNCTION tick
BEGIN
    VARIABLE now TIME
    VARIABLE hour INTEGER
    VARIABLE quarter INTEGER
    VARIABLE clock STRING
    CALL c0de/time/NOW
        RESULT result now
    CALL c0de/strings/FORMAT
        PARAMETER value now ;
        PARAMETER format "%tT" ;
        RESULT result clock
    CALL c0de/time/HOUR
        PARAMETER time now ;
        RESULT result hour
    CALL c0de/math/DIV
        PARAMETER dividend hour ;
        PARAMETER divisor 6 ;
        RESULT result quarter
    CALL LOCATE
        PARAMETER row 3 ;
        PARAMETER column 12 ;
    CALL PRINT
        PARAMETER value clock ;
    CALL LOCATE
        PARAMETER row 5 ;
        PARAMETER column 9 ;
    CALL PRINT
        PARAMETER value greetings[quarter] ;
END FUNCTION

Der Tag hat vier Viertel zu sechs Stunden, und DIV aus c0de/math macht aus der Stunde die Nummer ihres Viertels, 0 bis 3, die den Gruß aus dem Array auswählt. Die Grüße sind auf dieselbe Länge aufgefüllt, damit ein kürzerer einen längeren ganz überschreibt.

Mehr dazu ​