Spielzeit und echte Zeit
Ein Ball, der über eine Anzeige hüpft, und eine Anzeige, die den Tag und die Uhrzeit der Minecraft-Welt zeigt: Sonnenaufgang, Tag, Sonnenuntergang oder Nacht.
Funktionen: SLEEP und TICKS aus c0de/minecraft.
Was du brauchst
Für die Animation: einen Auslöserblock mit Knopf und einen Anzeigeblock; wahlweise eine Variablenkarte delay vom Typ INTEGER. Für Tag und Nacht: einen Zeitgeberblock und einen zweiten Anzeigeblock; um phase allein auszuprobieren, eine Variablenkarte ticks vom Typ INTEGER und zwei nicht initialisierte Karten für den Auslöserblock. Für die Übungen: eine weitere nicht initialisierte Karte.
Die Idee
Die anderen Rezepte von c0de/time lesen die echte Zeit, die Uhr des Servers. Minecraft hat eine zweite Uhr, die Spielzeit, gezählt in Ticks. Wenn der Server mitkommt, hat eine Sekunde 20 Ticks, und ein Minecraft-Tag mit 24 000 Ticks dauert 20 Minuten.
- SLEEP hält ein Programm für eine Zahl von Ticks an, 1 bis 72 000 (eine Stunde). So wartet ein Programm: auf das nächste Bild einer Animation, darauf, dass eine Tür schließt, auf den nächsten Versuch.
- TICKS gibt die Spielzeit der Welt zurück, die Ticks seit ihrer Erschaffung. Der Rest
\ 24000ist die Tageszeit: 0 ist der Sonnenaufgang um 6:00, 6000 Mittag, 12 000 Sonnenuntergang und 18 000 Mitternacht.
Eine Animation
PROGRAM bouncer
NOOP
INCLUDE c0de/time
NOOP
FUNCTION bounce
PARAMETER rounds INTEGER 3
PARAMETER delay INTEGER 2
BEGIN
CALL CLS
FOR round INTEGER 1 ; rounds ;
BEGIN
FOR column INTEGER 0 ; 14 ;
BEGIN
CALL LOCATE
PARAMETER row 3 ;
PARAMETER column column ;
CALL PRINT
PARAMETER value " o" ;
CALL c0de/time/SLEEP
PARAMETER ticks delay ;
END FOR
FOR column INTEGER 14 ; 0 ; -1 ;
BEGIN
CALL LOCATE
PARAMETER row 3 ;
PARAMETER column column ;
CALL PRINT
PARAMETER value "o " ;
CALL c0de/time/SLEEP
PARAMETER ticks delay ;
END FOR
END FOR
END FUNCTIONBinde einen Anzeigeblock an das Programm bouncer und die Funktion bounce, stelle den Auslöserblock genauso ein und drücke seinen Knopf. Ein Ball läuft dreimal durch Zeile 3 der Anzeige hin und zurück.

So funktioniert es
- Ein Bild, ein SLEEP. Jeder Durchlauf der inneren Schleifen zeichnet ein Bild und wartet dann
delayTicks. - Über den alten Ball zeichnen. Auf dem Weg nach rechts schreibt PRINT
" o": Das Leerzeichen löscht den Ball des letzten Bildes eine Spalte weiter links. Auf dem Rückweg löscht"o "den rechts daneben. Kein CLS, kein Flackern. - Die Zeilen zählen mit. Der Cursor braucht für jede Zeile einen Tick, also dauert ein Bild etwa vier Ticks plus das SLEEP. Ein Programm läuft nie schneller als eine Zeile pro Tick.
- Parameter mit Standardwerten.
roundsunddelayhaben Standardwerte, also braucht der Auslöserblock keine Karten. Lege eine INTEGER-Variablenkartedelaymit 5 hinein, dann wird der Ball langsamer. Mit 0 löst SLEEP INVALID_ARGUMENT aus, und der Prozess stürzt ab.
Tag und Nacht
PROGRAM daynight
NOOP
INCLUDE c0de/minecraft
INCLUDE c0de/math
INCLUDE c0de/strings
NOOP
FUNCTION phase
PARAMETER ticks INTEGER
RESULT day INTEGER
RESULT clock STRING
RESULT text STRING
BEGIN
VARIABLE time INTEGER
VARIABLE hour INTEGER
VARIABLE minute INTEGER
VARIABLE digits STRING
CALL c0de/math/DIV
PARAMETER dividend ticks ;
PARAMETER divisor 24000 ;
RESULT result day
ASSIGN day day + 1 ;
ASSIGN time ticks \ 24000 ;
CALL c0de/math/DIV
PARAMETER dividend time ;
PARAMETER divisor 1000 ;
RESULT result hour
ASSIGN hour (hour + 6) \ 24 ;
CALL c0de/math/DIV
PARAMETER dividend (time \ 1000) * 60 ;
PARAMETER divisor 1000 ;
RESULT result minute
CALL c0de/strings/FORMAT
PARAMETER value hour ;
PARAMETER format "%02d" ;
RESULT result clock
CALL c0de/strings/FORMAT
PARAMETER value minute ;
PARAMETER format ":%02d" ;
RESULT result digits
ASSIGN clock clock ⊕ digits ;
ASSIGN text "Day" ;
IF time ≥ 12000 ;
BEGIN
ASSIGN text "Sunset" ;
END IF
IF time ≥ 13000 ;
BEGIN
ASSIGN text "Night" ;
END IF
IF time ≥ 23000 ;
BEGIN
ASSIGN text "Sunrise" ;
END IF
END FUNCTION
NOOP
FUNCTION show
BEGIN
VARIABLE ticks INTEGER
VARIABLE day INTEGER
VARIABLE clock STRING
VARIABLE text STRING
CALL c0de/minecraft/TICKS
RESULT result ticks
CALL phase
PARAMETER ticks ticks ;
RESULT day day
RESULT clock clock
RESULT text text
CALL CLS
CALL PRINT
PARAMETER value "Day " ⊕ day ;
CALL PRINT
PARAMETER value clock ;
CALL PRINT
PARAMETER value text ;
END FUNCTIONBinde den zweiten Anzeigeblock an daynight / show, stelle den Zeitgeberblock genauso und auf einen Abstand von 100 Ticks ein. Die Anzeige zeigt die Nummer des Minecraft-Tages, die Uhrzeit der Welt und was der Himmel gerade tut:
Day 3
18:30
SunsetSo funktioniert es
- Von Ticks zur Uhrzeit. Eine Minecraft-Stunde hat 1000 Ticks, und Tick 0 ist 6:00 Uhr morgens. Die Stunde ist also die Zahl der ganzen Tausender plus 6, und die Minute der Rest von tausend Ticks mal 60 / 1000.
- Die Tageszählung. Alle 24 000 Ticks beginnt ein neuer Tag;
phasezählt ab Tag 1. - Die Phasen werden von der frühesten zur spätesten verglichen: Day, dann Sunset ab 12 000, Night ab 13 000 und Sunrise ab 23 000. Ein späteres IF überschreibt ein früheres.
- TICKS ist nicht die Tageszeit. TICKS zählt jeden Tick der Welt. Schlafen im Bett oder
/time setverändern die Sonne, aber nicht TICKS. In einer Welt, in der jemand geschlafen hat, zeigt die Anzeige die falsche Phase; in einer Welt, in der niemand schläft, stimmt sie. - TICKS braucht das Spiel. Programme mit c0de/minecraft laufen nur in Minecraft, deshalb nimmt
phasedie Ticks als Parameter: Probier es mit einem Auslöserblock, der aufphaseeingestellt ist, einer INTEGER-Variablenkarteticksmit 12 500 und zwei nicht initialisierten Karten aus (die Parameterkarte macht Platz für das dritte Ergebnis). Die Ergebnisse sind 1,18:30undSunset.
Probier es selbst
- Setze
delayauf 1. Warum ist der Ball nicht doppelt so schnell wie mit 2?
Lösung
Ein Bild braucht etwa vier Ticks für die Zeilen der Schleife und delay Ticks SLEEP: sechs Ticks mit 2, fünf Ticks mit 1. Nur das SLEEP wird kürzer. Für einen schnelleren Ball bewege ihn zwei Spalten pro Bild.
- SLEEP 20 ist nur dann eine Sekunde, wenn der Server mitkommt. Miss, wie viele Ticks deine Welt wirklich pro Sekunde läuft: Lies TICKS und NOW, schlafe 200 Ticks und lies beide noch einmal.
Lösung
PROGRAM serverspeed
NOOP
INCLUDE c0de/minecraft
INCLUDE c0de/time
INCLUDE c0de/strings
NOOP
FUNCTION measure
RESULT speed FLOAT
BEGIN
VARIABLE firstTick INTEGER
VARIABLE lastTick INTEGER
VARIABLE firstTime TIME
VARIABLE lastTime TIME
VARIABLE text STRING
CALL c0de/minecraft/TICKS
RESULT result firstTick
CALL c0de/time/NOW
RESULT result firstTime
CALL c0de/time/SLEEP
PARAMETER ticks 200 ;
CALL c0de/minecraft/TICKS
RESULT result lastTick
CALL c0de/time/NOW
RESULT result lastTime
ASSIGN speed (lastTick - firstTick) / ((lastTime - firstTime) / 1000) ;
CALL c0de/strings/FORMAT
PARAMETER value speed ;
PARAMETER format "%.1f" ;
RESULT result text
CALL PRINT
PARAMETER value "Ticks per second: " ⊕ text ;
END FUNCTIONStelle den Auslöserblock der Animation auf serverspeed / measure, leg eine nicht initialisierte Karte für das Ergebnis speed hinein und binde auch seinen Anzeigeblock an serverspeed / measure. Nach 200 Ticks zeigt die Anzeige Ticks per second: 20.0, und speed enthält dieselbe Zahl.
Die Ticks zwischen den beiden Messungen geteilt durch die Sekunden dazwischen. Ein gesunder Server zeigt 20.0, ein ausgelasteter weniger – und dann dauert jedes SLEEP und jedes Programm in echter Zeit länger.
Mehr dazu
- Handbuch SLEEP, TICKS und NOW
- Bibliotheken: c0de/time und c0de/minecraft
- Der Cursor
- Anzeigeblock, Auslöserblock und Zeitgeberblock