Stoppuhr und Reaktionstest
Eine Stoppuhr für Rennen in deiner Welt: Ein Knopf startet sie, ein anderer hält sie an, und eine Anzeigewand zeigt die Zeit auf die Millisekunde genau. Danach ein Reaktionstest auf einem Laptop: Wie schnell drückst du eine Taste, wenn „GO!“ erscheint?
Funktionen: TIMER, MILLISECOND und Rechnungen mit TIME-Werten, dazu NOW, SLEEP und FORMAT.
Was du brauchst
Für die Stoppuhr: zwei Auslöserblöcke mit je einem Knopf, eine Anzeigewand aus 2 × 1 Anzeigeblöcken, einen Trichter, eine Truhe und ein paar nicht initialisierte Variablenkarten. Für den Reaktionstest: einen Auslöserblock mit Knopf und einen Laptop.
Die Idee
Zeit messen heißt, zweimal auf die Uhr zu schauen und abzuziehen. c0de hat dafür zwei Uhren:
- NOW gibt einen TIME-Wert zurück, einen Zeitpunkt in Millisekunden. Zwei TIME-Werte voneinander abgezogen ergeben einen INTEGER, die Millisekunden dazwischen. Ein TIME-Wert kann als Variablenkarte reisen, also kann ein Prozess die Stoppuhr starten und ein anderer sie anhalten.
- TIMER gibt die Sekunden seit Mitternacht als FLOAT zurück, etwa
32703.25. Das ist praktisch innerhalb eines Prozesses: keine TIME-Werte, nur eine Subtraktion zweier Zahlen.
Die Stoppuhr
PROGRAM stopwatch
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
NOOP
FUNCTION stamp
PARAMETER time TIME
RESULT text STRING
BEGIN
VARIABLE millis INTEGER
VARIABLE digits STRING
CALL c0de/strings/FORMAT
PARAMETER value time ;
PARAMETER format "%tT" ;
RESULT result text
CALL c0de/time/MILLISECOND
PARAMETER time time ;
RESULT result millis
CALL c0de/strings/FORMAT
PARAMETER value millis ;
PARAMETER format ".%03d" ;
RESULT result digits
ASSIGN text text ⊕ digits ;
END FUNCTION
NOOP
FUNCTION start
RESULT started TIME
BEGIN
CALL c0de/time/NOW
RESULT result started
END FUNCTION
NOOP
FUNCTION stop
PARAMETER started TIME
RESULT seconds FLOAT
BEGIN
VARIABLE now TIME
VARIABLE text STRING
CALL c0de/time/NOW
RESULT result now
ASSIGN seconds (now - started) / 1000 ;
CALL CLS
CALL stamp
PARAMETER time started ;
RESULT text text
CALL PRINT
PARAMETER value "Start " ⊕ text ;
CALL stamp
PARAMETER time now ;
RESULT text text
CALL PRINT
PARAMETER value "Stop " ⊕ text ;
CALL c0de/strings/FORMAT
PARAMETER value seconds ;
PARAMETER format "%.3f" ;
RESULT result text
CALL PRINT
PARAMETER value "Time " ⊕ text ⊕ " s" ;
END FUNCTIONAufbauen und starten
- Setze Auslöserblock A und stelle ihn auf
stopwatch/startein. Lege ein paar nicht initialisierte Variablenkarten in seine Eingabe: Jeder Start braucht eine für sein Ergebnisstarted. - Setze Auslöserblock B direkt neben A und stelle ihn auf
stopwatch/stopein. B ist der einzige Block mit Inventar, der A berührt, also geht die Ausgabe von A von selbst in B. - Setze unter B einen Trichter, der in die Truhe führt.
- Setze an jeden Auslöserblock einen Knopf und binde die Anzeigewand an
stopwatch/stop.
Drücke den Knopf an A: Die Karte started geht in B. Drücke den Knopf an B: Die Wand zeigt
Start 09:04:50.655
Stop 09:05:03.000
Time 12.345 sund die Karte seconds mit dem Wert 12.345 fällt in die Truhe – eine Liste all deiner Zeiten.

So funktioniert es
- Die Zeit reist als Karte.
startgibt nur NOW alsstartedzurück.stopnimmt sie als Parameter; die beiden Prozesse teilen also nichts außer dieser Karte. Drückst du A zweimal, warten zwei Karten in B: Der nächste Lauf nimmt eine für seinen Parameter und reicht die andere in die Truhe weiter. - Zeiten abziehen.
now - startedist die Zahl der Millisekunden. Mit/durch 1000 geteilt, wird daraus ein FLOAT in Sekunden, und%.3fschreibt ihn mit drei Nachkommastellen. - MILLISECOND.
%tTschreibt eine Uhrzeit auf die Sekunde genau.stamphängt mit MILLISECOND die Millisekunden an, 0 bis 999, von.%03dauf drei Stellen aufgefüllt. - Wie genau ist sie? NOW ist auf die Millisekunde genau, aber ein Prozess startet zu einem Tick, und der Cursor geht eine Zeile pro Tick weiter. Eine Stoppuhr im Spiel ist also auf etwa eine Zwanzigstelsekunde genau. Beide Knöpfe warten auf dieselbe Weise, deshalb hebt sich der Fehler größtenteils auf.
Der Reaktionstest
PROGRAM reaction
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
INCLUDE c0de/math
NOOP
FUNCTION rate
PARAMETER seconds FLOAT
RESULT verdict STRING
BEGIN
ASSIGN verdict "Wake up!" ;
IF seconds < 0.5 ;
BEGIN
ASSIGN verdict "Good" ;
END IF
IF seconds < 0.3 ;
BEGIN
ASSIGN verdict "Lightning fast!" ;
END IF
END FUNCTION
NOOP
FUNCTION react
BEGIN
VARIABLE chance FLOAT
VARIABLE wait INTEGER
VARIABLE key STRING
VARIABLE start FLOAT
VARIABLE stop FLOAT
VARIABLE seconds FLOAT
VARIABLE text STRING
VARIABLE verdict STRING
CALL CLS
CALL PRINT
PARAMETER value "Press a key to start" ;
REPEAT
BEGIN
CALL INKEY
RESULT result key
END REPEAT key = "" ;
CALL PRINT
PARAMETER value "Wait for GO!" ;
CALL c0de/math/RANDOM
RESULT result chance
CALL c0de/math/INT
PARAMETER value 40 + chance * 60 ;
RESULT result wait
CALL c0de/time/SLEEP
PARAMETER ticks wait ;
CALL PRINT
PARAMETER value "GO!" ;
CALL c0de/time/TIMER
RESULT result start
REPEAT
BEGIN
CALL INKEY
RESULT result key
END REPEAT key = "" ;
CALL c0de/time/TIMER
RESULT result stop
IF stop < start ;
BEGIN
ASSIGN stop stop + 86400 ;
END IF
ASSIGN seconds stop - start ;
CALL c0de/strings/FORMAT
PARAMETER value seconds ;
PARAMETER format "%.3f" ;
RESULT result text
CALL rate
PARAMETER seconds seconds ;
RESULT verdict verdict
CALL PRINT
PARAMETER value "Your time: " ⊕ text ⊕ " s" ;
CALL PRINT
PARAMETER value verdict ;
END FUNCTIONAufbauen und starten
Binde den Laptop an reaction / react, stelle den Auslöserblock genauso ein und drücke seinen Knopf. Öffne den Laptop und drücke eine Taste, um zu beginnen. Nach zwei bis fünf Sekunden erscheint „GO!“: Drücke so schnell du kannst eine Taste. Der Laptop zeigt deine Zeit und ein Urteil.
So funktioniert es
- Eine zufällige Wartezeit. RANDOM und INT wählen zwischen 40 und 99 Ticks, und SLEEP wartet so lange, damit du nicht erraten kannst, wann „GO!“ kommt.
- TIMER um die Schleife. TIMER wird direkt nach „GO!“ und direkt nach der Taste gelesen. Die Schleife fragt INKEY, bis eine Taste da ist, also ist der Unterschied deine Reaktionszeit – plus ein oder zwei Ticks des Cursors.
- Mitternacht. TIMER beginnt um Mitternacht wieder bei 0. Ist
stopkleiner alsstart, lief der Test über Mitternacht, und ein Tag mit 86 400 Sekunden wird addiert. rateist eine eigene Funktion. Sie nimmt die Sekunden als Parameter und lässt sich deshalb mit festen Werten wie 0,25 oder 0,8 testen, ohne auf eine echte Reaktion zu warten.
Probier es selbst
- Tasten, die vor „GO!“ gedrückt werden, warten auf INKEY; wer zu früh drückt, bekommt also eine perfekte Zeit. Erwische die Schummler: Wartet direkt nach dem SLEEP schon eine Taste, schreibe „Too early!“ und hör auf.
Lösung
PROGRAM reaction
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
INCLUDE c0de/math
NOOP
FUNCTION rate
PARAMETER seconds FLOAT
RESULT verdict STRING
BEGIN
ASSIGN verdict "Wake up!" ;
IF seconds < 0.5 ;
BEGIN
ASSIGN verdict "Good" ;
END IF
IF seconds < 0.3 ;
BEGIN
ASSIGN verdict "Lightning fast!" ;
END IF
END FUNCTION
NOOP
FUNCTION react
BEGIN
VARIABLE chance FLOAT
VARIABLE wait INTEGER
VARIABLE key STRING
VARIABLE start FLOAT
VARIABLE stop FLOAT
VARIABLE seconds FLOAT
VARIABLE text STRING
VARIABLE verdict STRING
CALL CLS
CALL PRINT
PARAMETER value "Press a key to start" ;
REPEAT
BEGIN
CALL INKEY
RESULT result key
END REPEAT key = "" ;
CALL PRINT
PARAMETER value "Wait for GO!" ;
CALL c0de/math/RANDOM
RESULT result chance
CALL c0de/math/INT
PARAMETER value 40 + chance * 60 ;
RESULT result wait
CALL c0de/time/SLEEP
PARAMETER ticks wait ;
CALL INKEY
RESULT result key
IF key ≠ "" ;
BEGIN
CALL PRINT
PARAMETER value "Too early!" ;
RETURN
END IF
CALL PRINT
PARAMETER value "GO!" ;
CALL c0de/time/TIMER
RESULT result start
REPEAT
BEGIN
CALL INKEY
RESULT result key
END REPEAT key = "" ;
CALL c0de/time/TIMER
RESULT result stop
IF stop < start ;
BEGIN
ASSIGN stop stop + 86400 ;
END IF
ASSIGN seconds stop - start ;
CALL c0de/strings/FORMAT
PARAMETER value seconds ;
PARAMETER format "%.3f" ;
RESULT result text
CALL rate
PARAMETER seconds seconds ;
RESULT verdict verdict
CALL PRINT
PARAMETER value "Your time: " ⊕ text ⊕ " s" ;
CALL PRINT
PARAMETER value verdict ;
END FUNCTIONEin INKEY nach dem SLEEP genügt: Eine zu frühe Taste wartet dort noch. RETURN beendet react.
- Ein Rennen durch deinen Parkour dauert Minuten. Zeige die Zeit als
2:05.300statt125.300 s.
Lösung
PROGRAM stopwatch
NOOP
INCLUDE c0de/time
INCLUDE c0de/strings
INCLUDE c0de/math
NOOP
FUNCTION stamp
PARAMETER time TIME
RESULT text STRING
BEGIN
VARIABLE millis INTEGER
VARIABLE digits STRING
CALL c0de/strings/FORMAT
PARAMETER value time ;
PARAMETER format "%tT" ;
RESULT result text
CALL c0de/time/MILLISECOND
PARAMETER time time ;
RESULT result millis
CALL c0de/strings/FORMAT
PARAMETER value millis ;
PARAMETER format ".%03d" ;
RESULT result digits
ASSIGN text text ⊕ digits ;
END FUNCTION
NOOP
FUNCTION start
RESULT started TIME
BEGIN
CALL c0de/time/NOW
RESULT result started
END FUNCTION
NOOP
FUNCTION stop
PARAMETER started TIME
RESULT seconds FLOAT
BEGIN
VARIABLE now TIME
VARIABLE text STRING
VARIABLE minutes INTEGER
VARIABLE rest STRING
CALL c0de/time/NOW
RESULT result now
ASSIGN seconds (now - started) / 1000 ;
CALL CLS
CALL stamp
PARAMETER time started ;
RESULT text text
CALL PRINT
PARAMETER value "Start " ⊕ text ;
CALL stamp
PARAMETER time now ;
RESULT text text
CALL PRINT
PARAMETER value "Stop " ⊕ text ;
CALL c0de/math/DIV
PARAMETER dividend now - started ;
PARAMETER divisor 60000 ;
RESULT result minutes
CALL c0de/strings/FORMAT
PARAMETER value ((now - started) \ 60000) / 1000 ;
PARAMETER format "%06.3f" ;
RESULT result rest
CALL PRINT
PARAMETER value "Time " ⊕ minutes ⊕ ":" ⊕ rest ;
END FUNCTIONDIV ergibt die ganzen Minuten der Millisekunden, der Rest \ 60000 den Rest der letzten Minute. %06.3f schreibt die Sekunden sechs Zeichen breit mit drei Nachkommastellen und führender Null, etwa 05.300.