Daten aus dem Web lesen
Eine Wetterstation für deine Basis: Gib den Namen einer Stadt ein, drück den Knopf, und eine Anzeigewand zeigt den Himmel, die Temperatur und den Wind dort, genau jetzt. Die Daten kommen von Open-Meteo, einem kostenlosen Wetterdienst, der weder ein Konto noch einen Schlüssel braucht.
Funktionen: HTTP_CONNECTION, HTTP_GET und FROM_JSON aus c0de/strings
Was du brauchst
Die Mod c0de net in deinem Spiel, einen Auslöserblock mit Knopf, eine Anzeigewand aus 2 × 1 Anzeigeblöcken (32 Spalten und 8 Zeilen), eine nicht initialisierte Variablenkarte und wahlweise eine Variablenkarte city vom Typ STRING mit dem Namen einer Stadt, zum Beispiel Berlin. Ohne sie zeigt das Programm Wien. Für die Übungen: zwei nicht initialisierte Variablenkarten und einen Zeitgeberblock.
Die Idee
Eine Web-API ist eine Webseite für Programme: Statt mit HTML antwortet sie mit JSON. Open-Meteo hat zwei davon. Die Geocoding-API macht aus einem Namen einen Ort mit seinen Koordinaten, und die Vorhersage-API nennt das Wetter an Koordinaten. Das Programm fragt also zweimal: zuerst „Wo liegt Berlin?“, dann „Wie ist das Wetter bei 52.52, 13.41?“.
c0de_net/http sendet die Anfragen. Eine Struktur HTTP_CONNECTION sagt, welcher Server gefragt wird und wie; HTTP_GET fragt nach einem Endpunkt, einem Pfad mit Abfrage, und gibt die Antwort als Text zurück. FROM_JSON liest diesen Text in Variablen deiner eigenen Typen. Du deklarierst nur die Teile der Antwort, die du brauchst; den Rest ignoriert FROM_JSON.
Die Anfragen kommen nicht vom Minecraft-Server, sondern vom Computer des Spielers, der den Knopf drückt, und dort muss c0de net installiert sein. Jeder Spieler kann das für seinen eigenen Computer abschalten.
Das Programm
PROGRAM weatherwall
NOOP
INCLUDE c0de/strings
INCLUDE c0de_net/http
NOOP
STRUCT place
BEGIN
name STRING
country STRING
latitude FLOAT
longitude FLOAT
END STRUCT
NOOP
STRUCT search
BEGIN
results ARRAY STRUCT place
END STRUCT
NOOP
STRUCT weather
BEGIN
temperature FLOAT TAG(json: "temperature_2m")
wind FLOAT TAG(json: "wind_speed_10m")
code INTEGER TAG(json: "weather_code")
END STRUCT
NOOP
FUNCTION sky
PARAMETER code INTEGER
RESULT result STRING
BEGIN
ASSIGN result "Clear" ;
IF code ≥ 1 ;
BEGIN
ASSIGN result "Cloudy" ;
END IF
IF code ≥ 45 ;
BEGIN
ASSIGN result "Fog" ;
END IF
IF code ≥ 51 ;
BEGIN
ASSIGN result "Rain" ;
END IF
IF code ≥ 71 ;
BEGIN
ASSIGN result "Snow" ;
END IF
IF code ≥ 80 ;
BEGIN
ASSIGN result "Showers" ;
END IF
IF code ≥ 95 ;
BEGIN
ASSIGN result "Thunderstorm" ;
END IF
END FUNCTION
NOOP
FUNCTION show
PARAMETER city STRING "Vienna"
RESULT found BOOLEAN
BEGIN
VARIABLE api STRUCT c0de_net/http/HTTP_CONNECTION
VARIABLE answer STRING
VARIABLE places STRUCT search
VARIABLE town STRUCT place
VARIABLE now STRUCT weather TAG(json: "current")
VARIABLE count INTEGER
VARIABLE text STRING
ASSIGN api.use_ssl TRUE ;
ASSIGN api.server "geocoding-api.open-meteo.com" ;
ASSIGN api.timeout 10 ;
CALL c0de_net/http/HTTP_GET
PARAMETER connection api ;
PARAMETER endpoint "/v1/search?count=1&name=" ⊕ city ;
RESULT result answer
CALL c0de/strings/FROM_JSON
PARAMETER source answer ;
PARAMETER destination places ;
CALL LEN
PARAMETER value places.results ;
RESULT result count
CALL CLS
IF count = 0 ;
BEGIN
CALL PRINT
PARAMETER value "No city called " ⊕ city ;
RETURN
END IF
ASSIGN found TRUE ;
ASSIGN town places.results[0] ;
ASSIGN api.server "api.open-meteo.com" ;
CALL c0de_net/http/HTTP_GET
PARAMETER connection api ;
PARAMETER endpoint "/v1/forecast?latitude=" ⊕ town.latitude ⊕ "&longitude=" ⊕ town.longitude ⊕ "¤t=temperature_2m,wind_speed_10m,weather_code" ;
RESULT result answer
CALL c0de/strings/FROM_JSON
PARAMETER source answer ;
PARAMETER destination now ;
CALL sky
PARAMETER code now.code ;
RESULT result text
CALL PRINT
PARAMETER value town.name ⊕ ", " ⊕ town.country ;
CALL PRINT
PARAMETER value "" ;
CALL PRINT
PARAMETER value text ;
CALL PRINT
PARAMETER value now.temperature ⊕ " °C" ;
CALL PRINT
PARAMETER value "Wind " ⊕ now.wind ⊕ " km/h" ;
END FUNCTIONAufbauen und starten
- Baue die Anzeigewand aus zwei Anzeigeblöcken nebeneinander. Klicke einen davon mit rechts an, klicke die Knöpfe, bis sie
weatherwallundshowzeigen, und klicke auf ✔. - Stelle den Auslöserblock auf das Programm
weatherwallund die Funktionshow. Leg eine nicht initialisierte Variablenkarte in sein Eingabeinventar, und die Kartecity, wenn du eine andere Stadt als Wien willst. - Drück den Knopf. Nach einem Moment zeigt die Wand:
Vienna, Austria
Cloudy
6.2 °C
Wind 7.7 km/h
Die Ergebniskarte found ist TRUE. Für einen Namen, den Open-Meteo nicht kennt, etwa Xyzzyqx, zeigt die Wand No city called Xyzzyqx, und found ist FALSE.
So funktioniert es
- Eine Verbindung, zwei Server.
apiwird einmal eingerichtet:use_sslfür https, eintimeoutvon 10 Sekunden statt 60. Für die zweite Anfrage ändert sich nurserver. Der Endpunkt ist alles hinter dem Servernamen, auch die Abfrage nach dem?. - Die Geocoding-Antwort sieht aus wie
{"results": [{"name": "Vienna", "latitude": 48.20849, "longitude": 16.37208, "country": "Austria", …}]}, mit vielen weiteren Schlüsseln. Die Struktursearchhat das eine Elementresults, ein Array ausplace, undplacehat nur die vier Elemente, die das Programm braucht. - Kein Treffer ist kein Fehler. Für eine unbekannte Stadt hat die Antwort gar kein
results. FROM_JSON behält dann den Startwert des Elements, ein leeres Array, und LEN sagt 0. (Ein Tag in einer VARIABLE-Zeile, wieTAG(json: "results"), würde stattdessen UNKNOWN_KEY auslösen.) - Tags benennen um. Die Vorhersage nennt ihre Werte
temperature_2m,wind_speed_10mundweather_code. Die Tags in der Strukturweatherbilden sie auf kürzere Namen ab. Der Tag inVARIABLE now STRUCT weather TAG(json: "current")ist ein Pfad: FROM_JSON liest nur das Objektcurrentder Antwort. - Zahlen in den Endpunkt.
⊕macht aus den Koordinaten Text, so wird der Endpunkt zu/v1/forecast?latitude=48.20849&longitude=16.37208¤t=…. - Der Wettercode ist eine Zahl der WMO: 0 ist ein klarer Himmel, 1 bis 3 Wolken, 45 Nebel, 51 bis 67 Regen, 71 bis 77 Schnee, 80 bis 82 Schauer, ab 95 Gewitter.
skyprüft die Grenzen von unten nach oben, also gewinnt die letzte, die passt. - Fehler. Hat der Spieler kein c0de net oder antwortet Open-Meteo nicht, löst der CALL einen Fehler von c0de net aus, und der Prozess stürzt ab; der Auslöserblock zeigt ihn an. Wenn das Netz ausfällt zeigt, wie du sie abfängst.
Probier es selbst
- Zeige die niedrigste und die höchste Temperatur von morgen in Wien. Open-Meteo liefert Tageswerte mit
daily=temperature_2m_min,temperature_2m_max.
Lösung
PROGRAM weathertomorrow
NOOP
INCLUDE c0de/strings
INCLUDE c0de_net/http
NOOP
FUNCTION tomorrow
RESULT low FLOAT
RESULT high FLOAT
BEGIN
VARIABLE api STRUCT c0de_net/http/HTTP_CONNECTION
VARIABLE answer STRING
VARIABLE lows ARRAY FLOAT TAG(json: "daily.temperature_2m_min")
VARIABLE highs ARRAY FLOAT TAG(json: "daily.temperature_2m_max")
ASSIGN api.use_ssl TRUE ;
ASSIGN api.server "api.open-meteo.com" ;
ASSIGN api.timeout 10 ;
CALL c0de_net/http/HTTP_GET
PARAMETER connection api ;
PARAMETER endpoint "/v1/forecast?latitude=48.21&longitude=16.37&daily=temperature_2m_min,temperature_2m_max&forecast_days=2" ;
RESULT result answer
CALL c0de/strings/FROM_JSON
PARAMETER source answer ;
PARAMETER destination lows ;
CALL c0de/strings/FROM_JSON
PARAMETER source answer ;
PARAMETER destination highs ;
ASSIGN low lows[1] ;
ASSIGN high highs[1] ;
CALL PRINT
PARAMETER value "Tomorrow: " ⊕ low ⊕ " to " ⊕ high ⊕ " °C" ;
END FUNCTIONforecast_days=2 fragt nach heute und morgen, und jeder Tageswert kommt als Array mit einer Zahl pro Tag: {"daily": {"temperature_2m_min": [3.1, 4.0], …}}. Die Tags in den VARIABLE-Zeilen sind Pfade in die Antwort; Index 1 ist morgen. Eine Antwort lässt sich zweimal lesen, in verschiedene Variablen.
Um es zu starten, stelle den Auslöserblock auf weathertomorrow / tomorrow, leg zwei nicht initialisierte Variablenkarten für die Ergebnisse low und high hinein und drück den Knopf. Die zwei Karten kommen mit den Temperaturen heraus. Um auch die PRINT-Zeile Tomorrow: … to … °C zu sehen, binde die Anzeigewand an weathertomorrow / tomorrow.
- Halte die Wand aktuell, ohne den Knopf zu drücken.
Lösung
Nimm statt des Auslöserblocks einen Zeitgeberblock mit demselben Programm, derselben Funktion und einem Abstand von 18000 Ticks (15 Minuten; Open-Meteo aktualisiert seine aktuellen Werte alle 15 Minuten). Den Prozess eines Zeitgeberblocks startet niemand, also kommen die Anfragen vom Besitzer des Zeitgeberblocks, der online sein muss. Jede Sekunde zu fragen, brächte nichts und belastete nur den kostenlosen Dienst.
- Probier die Stadt
New York. Was passiert, und wie behebst du es?
Lösung
Der Prozess stürzt mit INVALID_ARGUMENT ab: Not a valid URL … (Illegal character in query). Eine URL darf keine Leerzeichen enthalten. Schreib die Stadt als New+York; in einer Abfrage steht + für ein Leerzeichen.
Mehr dazu
- c0de_net/http: Erste Schritte, HTTP_CONNECTION, HTTP_GET, Fehler
- FROM_JSON und JSON und YAML
- Daten und das Netzwerk: Typen, Tags und FROM_JSON im Detail
- Anzeigeblock und Zeitgeberblock
- Die Dokumentation von Open-Meteo nennt alle Werte, die die Vorhersage liefern kann